/* Open ImageFX macro */
parse arg file
    if (show(P,IMAGEFX.1)~=1) then
    address command 'run >nil: ImageFX4:ImageFX4 'file''
    else do
        address "IMAGEFX.1"
        loadbuffer new file
    end
exit

/* Usage: open Ram Disk: or open "Ram Disk:" or open dh1:hry/Galaga */
parse arg path '"'ces'"' /* odstrani z argumentu (napr "Ram Disk:") path uvozovky a prevede ho na promennou ces */
if ces = "" then do      /* jestlize je promenna ces prazdna (argument path neobsahuje uvozovky nebo neobsahuje nic) tak */
    if path = "" then do /* jestlize je argument path prazdny tak */
        say "Usage: open Ram Disk: or open ""Ram Disk:"" or open dh1:hry/Galaga"  /* vypise napovedu */
        exit             /* konec programu */
    end                  /* konec if */
    else                 /* jinak (argument path neni prazdny) */
        ces = path       /* promenna ces bude puvodni argument path (bez uvozovek) */
end                      /* konec if */

if ~exists(ces) then do  /* jestlize promenna ces (cesta k adresari) neexistuje tak */
    say "Device or directory" ces "not exists."  /* vypise chybu */
    exit                 /* konec programu */
end                      /* konec if */
address 'WORKBENCH'      /* volani Arexx adresy-portu Workbenche */
'WINDOW "'ces'" OPEN'    /* Arexx prikazy pro port Workbenche - okno -> promenna ces -> otevrit */

/* "$VER: opendr 0.1 (05.07.2015)"*/
/* Simple open drawer with requester ghh 2015 */
options results
address command 'requestfile Ram: TITLE="Select directory" DRAWERSONLY >t:pth'
if (rc ~= 0) then do
    address command 'delete >nil: t:pth'
    exit
end
call open('pt','t:pth','R')
path = readln('pt')
call close('pt')
address command 'delete >nil: t:pth'
parse var path '"'ces'"'
if ces = "" then do
    if path = "" then exit
    else
        ces = path
end
if ~exists(ces) then exit
address 'WORKBENCH'
'WINDOW "'ces'" OPEN'