MODULE 'dos/dosextens'

PROC main()
  DEF jo

   WriteF('0 existuje, 20 neexistuje\n')
   jo:=findAssign('ram disk:')
   WriteF('cislo \d\n',jo)
ENDPROC

PROC findAssign(name:PTR TO CHAR)
/* returns 0 if it exists otherwise it returns 20 */
  DEF db:PTR TO doslibrary
  DEF rootnode:PTR TO rootnode
  DEF dosinfo:PTR TO dosinfo
  DEF devicelist:PTR TO devlist
  DEF temp[256]:STRING
  DEF temp2[256]:STRING
  DEF i=0

  StrCopy(temp,name)
  WHILE temp[i]            ->hleda dvojtecku ve stringu
   IF(temp[i]=":")
     SetStr(temp,i)        ->zapise do stringu to co je pred dvojteckou
     i:=-1
   ENDIF
   EXIT i=-1
   i++
  ENDWHILE

  IF i<>-1 THEN RETURN 20  ->kdyz chybi dvojtecka

  db:= dosbase
  rootnode:= db.root
  dosinfo:= (rootnode.info << 2)
  devicelist:= (dosinfo.devinfo << 2)
  Forbid()
  WHILE(devicelist.next)
    bStrC(devicelist.name,temp2)
    IF(strCmpi(temp2,temp,ALL))
      Permit()
      RETURN 0
    ENDIF
    devicelist:=(devicelist.next << 2)
  ENDWHILE
  Permit()
ENDPROC 20

PROC strCmpi(test1:PTR TO CHAR, test2:PTR TO CHAR, len)
  /* case insensitive string compare */
  DEF i,l1,l2

  IF len=ALL
    l1:= StrLen(test1)
    l2:= StrLen(test2)
    IF l1<>l2 THEN RETURN FALSE
    len:= l1
  ENDIF

  FOR i:=0 TO len-1

    IF charToLower(test1[i])<>charToLower(test2[i]) THEN RETURN FALSE

  ENDFOR
ENDPROC TRUE

PROC charToLower(c)
  DEF str[1]:STRING
  str[0]:=c
  LowerStr(str)

ENDPROC str[0]

PROC bStrC(bstr:PTR TO CHAR,outbuf:PTR TO CHAR)

 DEF str:PTR TO CHAR
 DEF loop,counter

 counter:= 0
 str:= (bstr << 2)
 SetStr(outbuf,str[0])

 FOR loop:= 1 TO str[0]
   outbuf[counter]:= str[loop]
   counter++
 ENDFOR

ENDPROC
​

/*
  accessing the list of logical volumes is hairy under AmigaOS 1.x - it is
  "hidden" in the DosBase structure, and shared among all tasks.

  Effectively this means, we need to nest the retrieval of the assigns into
  Forbid()/Permit() calls to lock the assign list to prevent possible
  race conditions.

  Reminder: We need to do some BCPL->C conversion here
  BPTR are address pointers divided by 4, use BADDR to convert
  BSTR are BPTRs to 0-terminated ASCII char arrays with a prefix length byte

  For now, we will omit device typed entries, because writing/reading to them
  usually doesn't make too much sense.
*/
​